Excel Forum - Porady, Pomoc, Excel Help, Excel FAQ - PQ skrypt

Pawel07 · Starszy Forumowicz Wersja: Win Office 2016 Posty: 35

Cześć,

Mam kod w PQ, który grupuje wartości z tabeli po unikalnej marce auta. Pozostałe parametry nieunikalne dla marki auta przedstawia w kolejnych kolumnach dodatkowo z użyciem separatora w formie nowego wiersza.

Kod:

let
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
#"Pogrupowano wiersze" = Table.Group(Źródło, {"Marka"}, {{"data", each _, type table [Marka=text, #"Model (EN)"=text, Typ=text, #"Silnik (EN)"=text]}}),
#"Dodano kolumnę niestandardową" = Table.AddColumn(#"Pogrupowano wiersze", "Model", each Table.Column([data], "Model")),
#"Dodano kolumnę niestandardową1" = Table.AddColumn(#"Dodano kolumnę niestandardową", "Typ", each Table.Column([data], "Typ")),
#"Dodano kolumnę niestandardową2" = Table.AddColumn(#"Dodano kolumnę niestandardową1", "Silnik", each Table.Column([data], "Silnik")),
#"Wyodrębnione wartości" = Table.TransformColumns(#"Dodano kolumnę niestandardową2", {"Model", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text}),
#"Wyodrębnione wartości1" = Table.TransformColumns(#"Wyodrębnione wartości", {"Typ", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text}),
#"Wyodrębnione wartości2" = Table.TransformColumns(#"Wyodrębnione wartości1", {"Silnik", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text})
in
#"Wyodrębnione wartości2"

Chce uprościć liczbę kroków aby otrzymać ten sam efekt:

Kod:

let
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
#"Pogrupowano wiersze" = Table.Group(Źródło, {"Marka"}, {{"data", each _, type table [Marka=text, #"Model (EN)"=text, Typ=text, #"Silnik (EN)"=text]}}),
#"Dodano kolumnę niestandardową" = Table.AddColumn(#"Pogrupowano wiersze", {"Model", each Text.Combine(List.Transform(Table.Column([data], "Model"), _, Text.From), "#(lf)"), type text})
in
#"Dodano kolumnę niestandardową"

daje to taki komunikat błędu:

Cytat:

Expression.Error: Do funkcji przekazano następującą liczbę argumentów: 2; funkcja oczekiwała od 3 do 4 argumentów.
Szczegóły:
Pattern=
Arguments=[List]

Próbuje ale nie wiem gdzie brakuje dodatkowego argumentu.
W skrócie chciałbym otrzymać efekt końcowy jak kod u góry w jak najmniejszej liczbie kroków.
Czy da się ?
Proszę o pomoc

query.xlsm

Pobierz Plik ściągnięto 22 raz(y) 33.76 KB

Kaper · Wysłany: 12-04-2023, 14:54

Jak rozumiem chcesz zgrupować dwa kroki dodawanie kolumny niestandardowej i wyodrębnianie wartości w jeden krok.
Spróbuj tak:

Kod:

let
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
#"Pogrupowano wiersze" = Table.Group(Źródło, {"Marka"}, {{"data", each _, type table [Marka=text, #"Model (EN)"=text, Typ=text, #"Silnik (EN)"=text]}}),
#"Wyodrębnione wartości" = Table.TransformColumns(Table.AddColumn(#"Pogrupowano wiersze", "Model", each Table.Column([data], "Model")), {"Model", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text})
in
#"Wyodrębnione wartości"

Pawel07 · Starszy Forumowicz Wersja: Win Office 2016 Posty: 35

To jest to.
Po grupowaniu oszczędzam liczbe kroków o 50%

Korzystając z podpowiedzi rozwinełem zapytanie o 2 kolejne kroki. Czyli oprócz modelu jak wyżej dodałem typ i silnik

Kod:

let
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
#"Pogrupowano wiersze" = Table.Group(Źródło, {"Marka"}, {{"data", each _, type table [Marka=text, #"Model (EN)"=text, Typ=text, #"Silnik (EN)"=text]}}),
model = Table.TransformColumns(Table.AddColumn(#"Pogrupowano wiersze", "Model", each Table.Column([data], "Model")), {"Model", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text}),
typ = Table.TransformColumns(Table.AddColumn(#"model", "Typ", each Table.Column([data], "Typ")), {"Typ", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text}),
silnik = Table.TransformColumns(Table.AddColumn(#"typ", "Silnik", each Table.Column([data], "Silnik")), {"Silnik", each Text.Combine(List.Transform(_, Text.From), "#(lf)"), type text})
in
silnik

Czy można to "zbić" w jeden krok ? Czyli w jednym kroku powstałyby 3 kolumny model, typ i silnik ?

Dziekuję i pozdrawiam

PS

query.xlsm

Pobierz Plik ściągnięto 18 raz(y) 31.09 KB

master_mix · Wysłany: 12-04-2023, 22:42

o to chodzi?

Kod:

let
in
Table.Group(
Excel.CurrentWorkbook(){[Name="dane"]}[Content],
"Marka",
{
{"Model", each Text.Combine([Model],"#(lf)")},
{"Typ", each Text.Combine([Typ],"#(lf)")},
{"Silnik", each Text.Combine([Silnik],"#(lf)")}
}
)

Pawel07 · Starszy Forumowicz Wersja: Win Office 2016 Posty: 35

No lekko mnie zatkało :shock:

Ostatecznie dla moich potrzeb nieco zmodyfikowałem kod:

Kod:

let
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
grupowanie = Table.Group(Źródło,
"Marka",
{
{"Model", each Text.Combine([Model],"#(lf)")},
{"Typ", each Text.Combine([Typ],"#(lf)")},
{"Silnik", each Text.Combine([Silnik],"#(lf)")}
}
)
in
grupowanie

Panowie,
bardzo dziękuje
traktuje to jako bezcenną lekcję

Pozdrawiam
PS

Bill Szysz · Wysłany: 14-04-2023, 11:43

Możesz jeszcze w ten sposób:

Kod:

let
Rodzaj = {"Model", "Typ", "Silnik"},
Źródło = Excel.CurrentWorkbook(){[Name="dane"]}[Content],
grupowanie = Table.Group(Źródło,
"Marka",
List.Transform(Rodzaj, (x) => {x, each Text.Combine(Table.Column(_, x),"#(lf)")})
)
in
grupowanie

W takim przypadku definiujesz sobie kolumny jakich chcesz użyć (w kroku "Rodzaj")
Możesz również wybór kolumn wrzucic do arkusza i z jego poziomu decydowac o tym jakie kolumny maja podlegac przekształceniom. (to juz kosmetyka)