Excel Forum - Porady, Pomoc, Excel Help, Excel FAQ - Excel online

Wilkownia80 · Świeżak Wersja: Mac Office 2019 Posty: 4

Cześć.
Mam problem, po przeniesieniu Excela do teamsa, formuła przestała działać:

=FRAGMENT.TEKSTU(KOMÓRKA("nazwa_pliku";$A$1);ZNAJDŹ("]";KOMÓRKA("nazwa_pliku";$A$1);1)+1;10)

Jest jakiś sposób w Excel online, aby pobierać nazwę arkusza do komórki ?
Dziękuje

Maciej Gonet · Wysłany: 22-09-2024, 10:07

Chyba nie ma prostego i łatwego sposobu jeśli struktura skoroszytu jest dynamiczna.
Gdyby była statyczna, to można utworzyć listę wszystkich nazw arkuszy jako stałą tablicową np. lista, zapisać ją w Menedżerze nazw, a później odczytać funkcją INDEKS:

Kod:

=INDEKS(lista;ARKUSZ())

Funkcja ARKUSZ() zwraca numer bieżącego arkusza.

Jeśli struktura jest dynamiczna, to trzeba byłoby jakoś tę listę odświeżać, a nie znam sposobu jak to zrobić w wersji Online.

Jeśli to jest istotne, to może poszukaj jakiegoś obejścia. Do czego są potrzebne te nazwy arkuszy? Może można je zastąpić czymś innym?

Wilkownia80 · Świeżak Wersja: Mac Office 2019 Posty: 4

Nazwa arkusza to data, z której formuła pobierała informacje jaki to dzień tygodnia.

- od poniedziałek do piątku , dane dzielone na trzy zmiany robocze.
- sobota, niedziela, dane dzielone na dwie zmiany robocze.

Dziękuję.

Maciej Gonet · Wysłany: 22-09-2024, 21:37

I w arkuszach, w komórkach nigdzie nie ma tej daty, tylko w nazwie arkusza?
A skoroszyt to zbiór jakichś przypadkowych dat, czy na przykład cały miesiąc?
Wtedy - jak wiadomo, jaki to miesiąc i rok, można wykorzystać numer arkusza.

Wilkownia80 · Świeżak Wersja: Mac Office 2019 Posty: 4

Aktualnie każdy wpisuje datę ręcznie,
Skoroszyt to miesiąc, od pierwszego do ostatniego dnia danego miesiąca.
Jak wykorzystać numer arkusza ?
Dziękuję za podpowiedź.

Maciej Gonet · Wysłany: 23-09-2024, 08:18

Załóżmy, że w skoroszycie masz kolejne arkusze o dowolnych nazwach (ale wygodnie można użyć Arkusz1, Arkusz2 itd. albo zostawić tylko liczby).
Załóżmy, że skoroszyt dotyczy września 2024.
Wtedy w pierwszym arkuszu można wpisać:

Kod:

=DATA(2024;9;ARKUSZ())

albo

Kod:

="01.09.2024"+ARKUSZ()-1

Tu musisz użyć formatu daty, który rozpoznaje Twój komputer.
Te formuły można kopiować do kolejnych arkuszy i każdy następny będzie odpowiadał kolejnej dacie.

Jeszcze inna koncepcja na "odczytanie" nazwy arkusza.
Załóżmy, że pierwszy arkusz w skoroszycie nazywa się Arkusz1.
Chcemy widzieć jego nazwę w komórce A1.
Do komórki B1 wpisujemy:

Kod:

=Arkusz1!A1

Wynik można ukryć formatowaniem (biała czcionka).
W komórce A1 taki wpis:

Kod:

=FRAGMENT.TEKSTU(FORMUŁA.TEKST(B1);2;DŁ(FORMUŁA.TEKST(B1))-4)

Ta formuła wyciąga z tekstu formuły w B1 nazwę arkusza.
Ale co to daje? Tę nazwę arkusza trzeba i tak co najmniej raz wpisać.
Taka formuła jednak aktualizuje się automatycznie przy zmianie nazwy arkusza. Można również kopiować lub duplikować arkusze (całe) i formuła dostosuje się do nowego arkusza.
Ale sama formuła z nazwą arkusza po przekopiowaniu do innego arkusza nie zmieni się. Trzeba kopiować cały arkusz.

I jeszcze wariant tego samego z trochę dłuższą formułą, ale za to nie angażuje dodatkowej komórki:

Kod:

=JEŻELI(FAŁSZ;Arkusz1!$A$1;LET(ft;FORMUŁA.TEKST(ADR.POŚR("WK";FAŁSZ)); ZASTĄP(LEWY(ft;ZNAJDŹ("!";ft)-1);1;14;)))

Gdyby nie było funkcji LET, to tak:

Kod:

=JEŻELI(FAŁSZ;Arkusz1!$A$1;ZASTĄP(LEWY(FORMUŁA.TEKST(ADR.POŚR("WK";FAŁSZ)); ZNAJDŹ("!";FORMUŁA.TEKST(ADR.POŚR("WK";FAŁSZ)))-1);1;14;""))

Albo jeszcze tak:

Kod:

=JEŻELI(FAŁSZ;Arkusz1!$A$1;ZASTĄP(LEWY(FORMUŁA.TEKST(D1); ZNAJDŹ("!";FORMUŁA.TEKST(D1))-1);1;14;""))

W tym przypadku podajemy adres względny (tu D1) komórki, w której wpisujemy formułę.

Kaper · Wysłany: 23-09-2024, 09:06

Albo nie zakładajmy jaki może być układ arkuszy i danych w arkuszach tylko wykorzystajmy cenną poradę z FAQ: https://www.excelforum.pl...ika-vt59262.htm :tak

Wilkownia80 · Świeżak Wersja: Mac Office 2019 Posty: 4

Dziękuje za pomoc.
Udało się, działa. Umieściłem uproszczony plik w którym pokazuje jak to rozwiązałem.
Pewnie istnieje inne rozwiązanie tego zadania, ale najważniejsze że problem rozwiązany.
Jeszcze raz dziękuje :beer

Forum.xlsx

Pobierz Plik ściągnięto 14 raz(y) 50.72 KB

Maciej Gonet · Wysłany: 24-09-2024, 21:50

Trochę dziwnie to zrobiłeś. Arkusze 5. i 6.10 masz przestawione. To akurat sobota i niedziela, więc może nie widać różnicy, ale mogłoby trafić na inne dni.
Nie bardzo rozumiem, dlaczego kalendarz na październik odnosisz do 1.09. Chyba łatwiej zmienić datę miesiąca niż pamiętać jaką cyferkę wpisać jako korektę.