Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 67763 Skopiuj do schowka Zliczenie liczb parzystych i nieparzystych
Autor Wiadomość
alex008
świeżak


Wersja: Win Office 2016
Posty: 9
Wysłany: 06-04-2020, 19:55   Zliczenie liczb parzystych i nieparzystych

Cześć,

czy jest formuła, która pozwoli na zliczenie z tabeli ile jest liczb parzystych, a ile nieparzystych?
_________________
Alex008
ID posta: 385079 Skopiuj do schowka
 
 
umiejead 
Excel Expert


Wersja: Win Office 2013
Pomógł: 614 razy
Posty: 3271
Wysłany: 06-04-2020, 20:09   

Jest.
.
_________________
.
Jak poprawnie opisać problem: http://www.excelforum.pl/...ika-vt59262.htm
Chcesz precyzyjną odpowiedź - zadaj precyzyjne pytanie.
ID posta: 385081 Skopiuj do schowka
 
 
Asia_@. 
Excel Expert


Pomogła: 2626 razy
Posty: 4430
Wysłany: 06-04-2020, 20:11   

parzyste
Kod:
=SUMA.ILOCZYNÓW(--(MOD(A1:A20;2)=0))

nieparzyste
Kod:
=SUMA.ILOCZYNÓW(--(MOD(A1:A20;2)=1))
_________________
Pozdrawiam
Asia
ID posta: 385082 Skopiuj do schowka
 
 
ąćęłńóś
Excel Expert


Pomógł: 268 razy
Posty: 1288
Wysłany: 06-04-2020, 22:50   

alex008 napisał/a:
zliczenie z tabeli ile jest liczb

Upewnij nas jeszcze - chodzi o:
a) zliczenie/policzenie liczb ("sztuk" liczb) tj. ilość 'dwójek', 'czwórek', 'jedynek', 'trójek', itd.) ?
czy
b) zsumowanie liczb parzystych i/lub nieparzystych ?
ID posta: 385103 Skopiuj do schowka
 
 
alex008
świeżak


Wersja: Win Office 2016
Posty: 9
Wysłany: 07-04-2020, 11:21   

ąćęłńóś napisał/a:
alex008 napisał/a:
zliczenie z tabeli ile jest liczb

Upewnij nas jeszcze - chodzi o:
a) zliczenie/policzenie liczb ("sztuk" liczb) tj. ilość 'dwójek', 'czwórek', 'jedynek', 'trójek', itd.) ?
czy
b) zsumowanie liczb parzystych i/lub nieparzystych ?


chodzi o zliczenie/policzenie liczb ("sztuk" liczb) tj. ilość 'dwójek', 'czwórek', 'jedynek', 'trójek', itd.)
_________________
Alex008
ID posta: 385134 Skopiuj do schowka
 
 
colpix
Exceloholic


Pomógł: 70 razy
Posty: 242
Wysłany: 07-04-2020, 14:34   

Witam,

dobrze jest precyzyjnie zadawać pytanie i dodawać do swojego pytania jeszcze załącznik z układem danych i oczekiwanym wynikiem.

Otrzymałeś już dwie dobre odpowiedzi, że jest + formuła. Teraz "ciągnięty za język" odkrywasz kolejne karty, chociaż dalej nie wszystko - przynajmniej dla mnie - jest czytelne.

Czy Twoja tabela, jest tabelą czy tylko obramowałeś swoje dane, żeby wyglądało na tabelkę? Czy Twoje cyfry/liczby mogą się zmieniać? Nie chodzi o ilość występowania, tylko o to, że teraz masz np. do 100, a mogą zwiększyć swój zakres do 150?

Pytania jeszcze się mnożą, ale…
Cytat:

chodzi o zliczenie/policzenie liczb ("sztuk" liczb) tj. ilość 'dwójek', 'czwórek', 'jedynek', 'trójek', itd.)


np.: funkcja =licz.jeżeli(zakres;kryteria), czyli np. do zliczenia jedynek =licz.jeżeli(A1:F50;1)

Zobacz załącznik, byle jaki, ale Ty nie zrobiłeś żadnego :mrgreen: , zrobiłem do siódemek :lol: , tam troszkę więcej, formuły troszkę się różnią, bo wszystko zależy od…, ale to Tobie powinno zależeć, tak więc zadaj precyzyjnie pytanie + dodaj załącznik, żeby było wiadomo o co chodzi jeżeli nie o to chodzi :-/

Zliczanie liczb.xlsx
Pobierz Plik ściągnięto 7 raz(y) 10.65 KB

_________________
Nie jestem leniwy, jestem energooszczędny
Pozdrawiam
colpix
ID posta: 385167 Skopiuj do schowka
 
 
alex008
świeżak


Wersja: Win Office 2016
Posty: 9
Wysłany: 07-04-2020, 15:05   

Asia_@. napisał/a:
parzyste
Kod:
=SUMA.ILOCZYNÓW(--(MOD(A1:A20;2)=0))

nieparzyste
Kod:
=SUMA.ILOCZYNÓW(--(MOD(A1:A20;2)=1))


Bardzo Ci dziękuję za pomoc!
_________________
Alex008
ID posta: 385172 Skopiuj do schowka
 
 
umiejead 
Excel Expert


Wersja: Win Office 2013
Pomógł: 614 razy
Posty: 3271
Wysłany: 07-04-2020, 15:31   

Bez modulo:
Kod:
=SUMA.ILOCZYNÓW(--(A1:A20/2=ZAOKR.DO.CAŁK(A1:A20/2)))
=SUMA.ILOCZYNÓW(--(A1:A20/2<>ZAOKR.DO.CAŁK(A1:A20/2)))
_________________
.
Jak poprawnie opisać problem: http://www.excelforum.pl/...ika-vt59262.htm
Chcesz precyzyjną odpowiedź - zadaj precyzyjne pytanie.
ID posta: 385174 Skopiuj do schowka
 
 
Maciej Gonet 
Excel Expert


Wersja: Win Office 2016
Pomógł: 1596 razy
Posty: 5257
Wysłany: 07-04-2020, 15:56   

To do kompletu można dodać jeszcze inny wariant bez modulo:
Kod:
=SUMA.ILOCZYNÓW(--CZY.PARZYSTE(+$A$1:$A$20))
=SUMA.ILOCZYNÓW(--CZY.NIEPARZYSTE(+$A$1:$A$20))
odpowiednio dla parzystych i nieparzystych. Ale wszystkie te formuły będą działać tylko gdy w podanym zakresie faktycznie będą liczby, Jeśli część komórek będzie pusta, to wynik będzie zafałszowany, bo puste komórki zostaną policzone jako zera, czyli parzyste. W takim przypadku do każdego wzoru na parzyste trzeba dopisać korektę:
Kod:
-LICZ.PUSTE($A$1:$A$20)


LICZ_PARZYSTE_NIEPARZYSTE.xlsx
Pobierz Plik ściągnięto 6 raz(y) 8.51 KB

ID posta: 385176 Skopiuj do schowka
 
 
colpix
Exceloholic


Pomógł: 70 razy
Posty: 242
Wysłany: 08-04-2020, 00:23   

Witam,

Cytat:
Jeśli część komórek będzie pusta, to wynik będzie zafałszowany,...

to cenna uwaga, ale być może takie nie występują, tak samo, jak być może nie występują liczby wymierne np. 0,5 i 1,5.

Formuła
Kod:
=SUMA.ILOCZYNÓW(--CZY.PARZYSTE(+$A$2:$A$21))-LICZ.PUSTE($A$2:$A$21)

wartość 0,5 zalicza do parzystych, a na lekcjach z matematyki w TVP odnośnie liczb parzystych i nieparzystych, mówili, że parzyste to takie, które mają parę :lol: , a ja tam pary nie widzę. :cry: Wartość 1,5 natomiast jest zaliczana już do nieparzystych.

Formuły umiejead w tym względzie są poprawne.

:off Dzisiaj to w ogóle ciężko odróżnić pary od nie pary, bo trzeba co najmniej 2m za sobą chodzić :lol: , o ile w ogóle można wyjść, bo inaczej można dostać parzysty mandat do 30 tyś. - ma parę i parzy, a ja już nie mam pary w znaczeniu, że sił. :mrgreen:


Jeszcze taka propozycja z MOD, ale bez funkcji licz.puste

parzyste
Kod:
=SUMA.ILOCZYNÓW((MOD(A1:A20;2)=0)*(A1:A20<>""))

nieparzyste
Kod:
=SUMA.ILOCZYNÓW((MOD(A1:A20;2)<>0)*(A1:A20<>""))

Wszystkie te formuły zwrócą błąd #ARG! jeżeli w tabeli znajdzie się jakiś wyraz lub litera.
_________________
Nie jestem leniwy, jestem energooszczędny
Pozdrawiam
colpix
ID posta: 385207 Skopiuj do schowka
 
 
Maciej Gonet 
Excel Expert


Wersja: Win Office 2016
Pomógł: 1596 razy
Posty: 5257
Wysłany: 08-04-2020, 06:41   

Używanie funkcji CZY.PARZYSTE i CZY.NIEPARZYSTE w odniesieniu do liczb z częścią ułamkową nie za bardzo ma sens. Generalnie jeśli Excel oczekuje na liczbę całkowitą, a dostanie ułamek, to ignoruje część ułamkową (nie zaokrągla), tzn. 0,3; 0,5; 0,8 zostaną potraktowane jak zera (parzyste), a 1,2; 1,5 i 1,9 jak 1 (nieparzyste).
ID posta: 385210 Skopiuj do schowka
 
 
colpix
Exceloholic


Pomógł: 70 razy
Posty: 242
Wysłany: 08-04-2020, 10:30   

Reasumując. Wszystkie powyższe formuły są dobre pod warunkiem, że w zbiorze są tylko liczby całkowite, bo tylko takie mogą być parzystymi bądź nie. W przypadku występowania w zbiorze liczb z częścią ułamkową jak np. 1,5 wszystkie formuły – oprócz podane przez Asia_@ pod warunkiem, że w zbiorze nie ma pustych komórek- zwrócą błędny wynik, bo zaliczą wartość 1,5 jako liczbę nieparzystą, a ona nie może być nieparzystą - pomimo, iż nie ma pary :lough - bo nie jest liczbą całkowitą.

Przykład: w zbiorze liczb: 1, 2 i 1,5 jest jedna parzysta i jedna nieparzysta.

Moja poprawna formuła dla liczb nieparzystych:
Kod:
=SUMA.ILOCZYNÓW((MOD(A1:A20;2)=1)*(A1:A20<>""))
_________________
Nie jestem leniwy, jestem energooszczędny
Pozdrawiam
colpix
ID posta: 385218 Skopiuj do schowka
 
 
umiejead 
Excel Expert


Wersja: Win Office 2013
Pomógł: 614 razy
Posty: 3271
Wysłany: 08-04-2020, 10:40   

Może niech autor się wypowie: jakie dane będą się znajdować w pliku.
.
_________________
.
Jak poprawnie opisać problem: http://www.excelforum.pl/...ika-vt59262.htm
Chcesz precyzyjną odpowiedź - zadaj precyzyjne pytanie.
ID posta: 385220 Skopiuj do schowka
 
 
colpix
Exceloholic


Pomógł: 70 razy
Posty: 242
Wysłany: 08-04-2020, 10:53   

Mnie interesują bardziej wyniki zwracane przez formuły dla wartości z częścią ułamkową, rozważam teoretycznie i przyszłościowo, a nie dane autora, bo tam raczej będzie miał liczby całkowite, takie podał w przykładzie i już podziękował.

Kod:
=CZY.NIEPARZYSTE(1,5)
zwróci wynik prawda :roll: , a formuła

Kod:
=SUMA.ILOCZYNÓW(--(MOD(1,5;2)=1))
zwróci wynik 0 :-D . Ot, tylko tyle.
_________________
Nie jestem leniwy, jestem energooszczędny
Pozdrawiam
colpix
ID posta: 385222 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe