Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 64445 Skopiuj do schowka Grafik spłat - pojawiają się wszystkie osoby
Autor Wiadomość
plake 
Starszy Forumowicz


Posty: 42
Wysłany: 15-03-2019, 20:15   Grafik spłat - pojawiają się wszystkie osoby

Witam
Chcę zrobić sobie grafik spłat pożyczek w zakładzie pracy.
Plik w załączeniu.
Mam problem z formułą - na liście pojawiają mi się wszystkie osoby które dostały pożyczkę.
Kod:
=JEŻELI(CZY.BŁĄD(PODAJ.POZYCJĘ(MIN(JEŻELI((Grafik!D$1:AA$1<>"")*CZY.LICZBA(Grafik!D$3:AA$3)*(LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0);LICZ.JEŻELI(Grafik!D$1:AA$1;"<="&Grafik!D$1:AA$1)+1;2^99));LICZ.JEŻELI(Grafik!D$1:AA$1;"<="&Grafik!D$1:AA$1)+1;0));"";INDEKS(Grafik!D$1:AA$1;PODAJ.POZYCJĘ(MIN(JEŻELI((Grafik!D$1:AA$1<>"")*CZY.LICZBA(Grafik!D$3:AA$3)*(LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0);LICZ.JEŻELI(Grafik!D$1:AA$1;"<="&Grafik!D$1:AA$1)+1;2^99));LICZ.JEŻELI(Grafik!D$1:AA$1;"<="&Grafik!D$1:AA$1)+1;0)))

Czy da się tak zrobić aby na liście spłat za dany miesiąc (arkusz Wykaz) pojawiały się tylko osoby spłacające pożyczkę w danym miesiącu z arkusza Grafik?
W arkuszu Wykaz zrobiłem grafik spłat.
Problem opisałem w kolumnie K w arkuszu Wykaz.
Z góry dziękuję za pomoc.

zfss.xls
Pobierz Plik ściągnięto 24 raz(y) 88.5 KB

ID posta: 364311 Skopiuj do schowka
 
 
umiejead 
Excel Expert


Wersja: Win Office 2013
Pomógł: 322 razy
Posty: 1714
Wysłany: 15-03-2019, 20:21   

Cytat:
W komórce D1 zmianiam kod miesiąca

I to tyle udało ci się zrobić?
_________________
.
Jak poprawnie opisać problem: http://www.excelforum.pl/...ika-vt59262.htm
I dbajmy - proszę - o poprawną polszczyznę.
ID posta: 364312 Skopiuj do schowka
 
 
apollo
ExcelSpec


Pomógł: 1234 razy
Posty: 4296
Wysłany: 16-03-2019, 00:39   Re: Grafik spłat - pojawiają się wszystkie osoby

plake napisał/a:
Witam
Chcę zrobić sobie grafik spłat pożyczek w zakładzie pracy.

Musisz używać starej wersji Excel? Pytam bo masz plik XLS. Ja dopiero po napisaniu formuł zauważyłem, że masz XLS, a już nie mam ochoty przerobić na starszą wersję. ;-)
ID posta: 364319 Skopiuj do schowka
 
 
plake 
Starszy Forumowicz


Posty: 42
Wysłany: 16-03-2019, 14:06   

umiejead napisał/a:
Cytat:
W komórce D1 zmianiam kod miesiąca

I to tyle udało ci się zrobić?

Witam.
Niestety nie każdy posiada dużą wiedzę na temat excela.
Cały czas się uczę.
Miałem jednak nadzieję na jakąś poradę. Wiem że dla ekspertów to są proste tematy. Moja wiedza niestety nie jest jeszcze tak zaawansowana.

Dziękuję bardzo dla apollo za zainteresowanie i poświęcony czas.
Niestety mojego zakładu pracy nie stać na zakup nowszej wersji excela.
Jak masz napisaną formułę która działa w nowszej wersji excela to też bardzo o nią poproszę. Może kiedyś kupią mi w firmie nowszą wersję. :-/
Z góry dziękuję za pomoc.
ID posta: 364346 Skopiuj do schowka
 
 
apollo
ExcelSpec


Pomógł: 1234 razy
Posty: 4296
Wysłany: 16-03-2019, 16:18   

Masz w swojej wersji chyba wszystkie funkcje z wyjątkiem AGGREGATE.
Być może ktoś przerobi na SMALL (MIN.K). Ja w tej chwili mam trochę roboty.

Być może w nocy będę miał czas ;-)
----------
Jeśli chodzi o listę osób to zmieniam na
Kod:

=JEŻELI.BŁĄD(INDEKS(Grafik!D$1:AA$1;MOD(AGGREGATE(15;6;(NR.KOLUMNY(A$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;"<"&Grafik!D$1:AA$1)*1000)/(LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)/(Grafik!D$1:AA$1<>"");1);1000));"")


Lista ale bez osób z zerową spłatą powstaje z powyższej listy przez dodanie 1 warunku - spłata <> 0
Kod:

(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51 & Grafik!$B$4:$B$51;0);0))<>0)



Czyli Lista ale bez osób z zerową spłatą
Dla E16
Kod:

=JEŻELI.BŁĄD(INDEKS(Grafik!D$1:AA$1;MOD(AGGREGATE(15;6;(NR.KOLUMNY(A$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;"<"&Grafik!D$1:AA$1)*1000)/(LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)/(Grafik!D$1:AA$1<>"")/(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51 & Grafik!$B$4:$B$51;0);0))<>0);1);1000));"")


Dla F11
Kod:

=INDEKS({"styczeń";"luty";"marzec";"kwiecień";"maj";"czerwiec";"lipiec";"sierpień";"wrzesień";"październik";"listopad";"grudzień"};PODAJ.POZYCJĘ(D1;{"sty";"lut";"mar";"kwi";"maj";"cze";"lip";"sie";"wrz";"paź";"lis";"gru"};0))


zfss.xls
Pobierz Plik ściągnięto 13 raz(y) 84.5 KB

ID posta: 364353 Skopiuj do schowka
 
 
Asia_@. 
Excel Expert


Pomogła: 2391 razy
Posty: 4064
Wysłany: 16-03-2019, 17:29   

załącznik

zfss.xls
Pobierz Plik ściągnięto 17 raz(y) 88.5 KB

_________________
Pozdrawiam
Asia
ID posta: 364356 Skopiuj do schowka
 
 
apollo
ExcelSpec


Pomógł: 1234 razy
Posty: 4296
Wysłany: 17-03-2019, 01:11   

Podany wyżej (ostatni post przed tym postem w temacie) kod nie sortuje, kod pytającego sortuje, ale to sprawa mniej wagi.
Duża sprawa to, że podana formuła nie zwraca unikatów:

Np. przy E1 = 2019:
- Jeśli D1 = mar lub kwi to Tomasz ma 2 pozycie.
- Jeśli D1 = maj to i Tomasz i Jolanta mają po 2 pozycje.

Tomasz i Jolanta mają wymienione 2 spłaty zamiast sumy spłat.

itd.
-----------
Moja propozycja.

W pliku jest wersja:
B. Formuła w E16 dla listy bez spłat = 0
4. z obsługą błędów z sortowaniem


Wszystkie formuły trzeba zakończyć Ctrl + Shift + Enter

A. Formuła w E16 dla pełnej listy
1. bez obsługi błędów bez sortowania

Kod:

=INDEKS(Grafik!A$1:AA$1;MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"");NR.KOLUMNY(D$1:AA$1);"");1))


2. bez obsługi błędów z sortowaniem
Kod:

=INDEKS(Grafik!A$1:AA$1;MOD(MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"");NR.KOLUMNY(D$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;"<"&Grafik!D$1:AA$1)*1000;"");1);1000))


3. z obsługą błędów bez sortowania
Kod:

=JEŻELI(SUMA((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>""))=0;"";INDEKS(Grafik!A$1:AA$1;MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"");NR.KOLUMNY(D$1:AA$1);"");1)))


4. z obsługą błędów z sortowaniem
Kod:

=JEŻELI(SUMA((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>""""))=0;"""";
INDEKS(Grafik!A$1:AA$1;MOD(MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"""");NR.KOLUMNY(D$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;""<""&Grafik!D$1:AA$1)*1000;"""");1);1000)))


B. Formuła w E16 dla listy bez spłat = 0

1. bez obsługi błędów bez sortowaniem
Kod:

=INDEKS(Grafik!A$1:AA$1;MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0);NR.KOLUMNY(D$1:AA$1);"");1))


2. bez obsługi błędów z sortowaniem
Kod:

=INDEKS(Grafik!A$1:AA$1;MOD(MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0);NR.KOLUMNY(D$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;"<"&Grafik!D$1:AA$1)*1000;"");1);1000))


3. z obsługą błędów bez sortowania
Kod:

=JEŻELI(SUMA((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0))=0;"";INDEKS(Grafik!A$1:AA$1;MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0);NR.KOLUMNY(D$1:AA$1);"");1)))


4. z obsługą błędów z sortowaniem
Kod:

=JEŻELI(SUMA((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0))=0;"";INDEKS(Grafik!A$1:AA$1;MOD(MIN.K(JEŻELI((LICZ.JEŻELI(E$15:E15;Grafik!D$1:AA$1)=0)*(Grafik!D$1:AA$1<>"")*(SUMA.JEŻELI(Grafik!D$1:AA$1;Grafik!D$1:AA$1;INDEKS(Grafik!D$4:AA$51;PODAJ.POZYCJĘ($E$1&$D$1;Grafik!$A$4:$A$51&Grafik!$B$4:$B$51;0);0))<>0);NR.KOLUMNY(D$1:AA$1)+LICZ.JEŻELI(Grafik!D$1:AA$1;"<"&Grafik!D$1:AA$1)*1000;"");1);1000)))


zfss2.xls
Pobierz Plik ściągnięto 16 raz(y) 90 KB

ID posta: 364369 Skopiuj do schowka
 
 
plake 
Starszy Forumowicz


Posty: 42
Wysłany: 17-03-2019, 11:43   

Bardzo dziękuję wszystkim za pomoc. Szczególnie dla apollo.
Dla Asi_@ i apollo punkty dodane.
Mam teraz dokładnie to co chciałem.
Odkrywam coraz większe zalety excela. Koniecznie muszę zdobyć nowszą wersję.
Jestem już w średnim wieku (50+) i dzięki Waszej pomocy uczę się i czerpie radość z życia.
Pozdrawiam wszystkich.
Jeszcze raz dziękuję. :danke
ID posta: 364384 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe