Excel Forum - Porady, Pomoc, Excel Help, Excel FAQ - równanie z 2 niewiadomymi na podstawie danych z komórek

naat3 · świeżak Posty: 3

Witam serdecznie.
Mam taki problem. Mam dane w komórkach arkusza i znich narysowany wykres - serie danych w kolumnach (przykład w załączniku). Czy można z tych danych ułożyć równanie z 2 niewiadomymi tak aby pierwszą zmienną tego rówania były wartości z kolumny pierwszej hf (dowolne wartości od 0 do 12) natomiast drugą zmienną były wartości z wiersza nagłówkowego (dowolne kąty od 0 do 180 stopni) ?

Przykład na podstawie danych z tabeli gdzie:
y - wartość szukana (prędkość statku w węzłach)
x - pierwsza zmienna (wysokość fali w metrach)
z - druga zmienna (kąt fali w stopniach)

i ogólna postac równania y= ax +bz + c - może to być wielomian dowolnego stopnia
Chodzi o to żeby wstawiając do tego rówania np. za x1= 4, i z1=0 stopni otrzymać wartość która jest na przcięciu wiersza i kolumny czyli y1 = 11,3 , lub wstawiając za x2 = 8, oraz za z2=135 stopni to wtedy otrzymamy wartośc y2=9,9, lub wstawiając dowolną wartość pomiędzy np. za x3 =5 i np. za z3 =50 stopni otrzymać za y3 odpowiednio aproksymowaną wartość z tabeli?
Czy jest w ogóle możliwe wyznaczenie takiego rówania?
Pozdrawiam
naat3

tabela danych i wykres.jpg

Plik ściągnięto 21 raz(y) 163.22 KB

negatyv · Wysłany: 2012-01-26, 09:09

A czy to równanie nie powinno mieć postaci y = ax + bz + c? A to nie masz tej formuły w tej tabelce? Jest ukryta, czy w ogóle masz tylko to zdjęcie? To mi wygląda na zadanie z matematyki, a nie z Excela.

naat3 · świeżak Posty: 3

Tak oczywiście wzór poprawiłem. Powinien być y = ax + bz + c. Jest to problem matematyczny ale chcę sprawdzić czy można go rozwiązać za pomocą excela (bo nie wiem gdzie można indziej szukać rozwiązania niż na tym forum). Wartości w tabelce są wartościami szacowanymi i chcę znaleść do nich rówanie.
Pozdrawiam

negatyv · Wysłany: 2012-01-26, 19:41

Myślę, że tu nie ma co zgadywać, tylko spojrzeć do dobrej książki. "Sternika Jachtowego" Kolaszewskiego widziałem ostatni raz z osiem lat temu, ale może to Ci pomoże:
http://ocean.am.gdynia.pl...falo_wplyw.html

naat3 · świeżak Posty: 3

Dziękuje za podpowiedź. Wzór jest jak najbardziej ok. Ale mi chodzi o to aby stworzyć oryginalny wzór - np. wielomian na podstawie podanego zestawu danych. Są to dane empiryczne z rejsów i potrzeba jest znalezienia na ich podstawie równania z 2 niewiadomymi.

negatyv · Wysłany: 2012-02-02, 10:00

Na morzu byłem ledwie parę razy i używaliśmy raczej GPSa niż wzorów, ale nie opracujesz do danych empirycznych z prawdziwego rejsu wzoru, który będzie idealnie pasował do danych. Po prostu podczas prawdziwego rejsu warunki się zmieniają pomiędzy pomiarami. Zmienia się kąt do fali, jej wysokość, prędkość jachtu itp. To tak, jakbyś chciał pływać przy pomocy nawigacji zliczeniowej :)

Rycho · Excel Expert **Pomógł:** 192 razy Posty: 301

hej,
rozwiązaniem jest funkcja użytkownika interpolująca tabelę dwóch zmiennych.
(pisałem o tym wcześniej na innym forum ).

Dla tabeli prędkości w zakresie C2:H9
przykład:

Kod:

do K2: 5
do L2: 75
do M2: =Predkosc(K2;L2;$C$2:$H$9)

Kod funkcji:

Kod:

Function Predkosc(wysokosc As Double, kat As Double, _
T As Range) As Variant
Dim z1 As Double, z2 As Double
Dim x1 As Double, x2 As Double
Dim p1 As Double, p2 As Double

Predkosc = CVErr(xlErrNA)

z2 = T(1, 2)
z1 = T(1, T.Columns.Count)
x2 = T(2, 1)
x1 = T(T.Rows.Count, 1)

If wysokosc < x2 Or wysokosc > x1 _
Or kat < z2 Or kat > z1 Then Exit Function

'szukamy przedziałów Z'
z1 = T.Columns.Count
Do While kat < T(1, z1) And z1 > 0
z1 = z1 - 1
Loop
z2 = 2
Do While kat >= T(1, z2) And z2 < T.Columns.Count
z2 = z2 + 1
Loop

'szukamy przedziałów X'
x1 = T.Rows.Count
Do While wysokosc < T(x1, 1) And x1 > 2
x1 = x1 - 1
Loop
x2 = 2
Do While wysokosc >= T(x2, 1) And x2 < T.Rows.Count
x2 = x2 + 1
Loop

'interpolacja dwuliniowa'
'najpierw poziomo'
If z1 = z2 Then 'nie trzeba interpolować'
p1 = T(x1, z1)
p2 = T(x2, z1)
Else
p1 = T(x1, z1) + (T(x1, z2) - T(x1, z1)) * _
(kat - T(1, z1)) / (T(1, z2) - T(1, z1))
p2 = T(x2, z1) + (T(x2, z2) - T(x2, z1)) * _
(kat - T(1, z1)) / (T(1, z2) - T(1, z1))
End If

'a teraz pionowo'
If p1 = p2 Then
Predkosc = p1
Else
Predkosc = p1 + (p2 - p1) * (wysokosc - T(x1, 1)) / _
(T(x2, 1) - T(x1, 1))
End If
End Function