Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 70109 Skopiuj do schowka Lista rozwijana, hiperłącze (email)
Autor Wiadomość
bart.rybka1 
Świeżak


Wersja: Win Office 2019
Posty: 2
Wysłany: 10-02-2021, 16:38   Lista rozwijana, hiperłącze (email)

Dzień Dobry

Mam problem z listą rozwijaną, potrzebuje wprowadzić opcję w której po wybraniu jednej pozycji z listy rozwijanej pokaże się hiperłącze odsyłające do pustej wiadomości email. Kombinuje ale nie mogę dojść jak to zrobić. Załączam plik jeśli ktoś będzie tak uprzejmy i pomoże w tym.

Z góry dziękuje za pomoc :danke

LPA AUDIT.xlsx
Pobierz Plik ściągnięto 8 raz(y) 23.48 KB

ID posta: 400116 Skopiuj do schowka
 
 
umiejead 
Excel Expert


Wersja: Win Office 2013
Pomógł: 775 razy
Posty: 4174

Wysłany: 11-02-2021, 07:38   

Witamy na Forum.

Wytłumacz dokładniej jaki jest cel gry.
.
_________________
.
Jak poprawnie opisać problem: http://www.excelforum.pl/...ika-vt59262.htm
Chcesz precyzyjną odpowiedź - zadaj precyzyjne pytanie.
ID posta: 400142 Skopiuj do schowka
 
 
stingtanner
ExcelGaduła 500+


Wersja: Win Office 2013
Pomógł: 6 razy
Posty: 511
Wysłany: 11-02-2021, 08:12   

Witaj
Podszedłem troszkę inaczej do tematu, może przypadnie Ci do gustu.
Gdy wybierzesz z listy rozwijanej "OK", automatycznie zostanie stworzony nowy pusty email, bez tworzenia hiperłącza.

Swoją droga nie podałeś, gdzie takie hiperłącze miało by się tworzyć.

LPA AUDIT.xlsm
Pobierz Plik ściągnięto 3 raz(y) 37.66 KB

ID posta: 400143 Skopiuj do schowka
 
 
Artik 



Wersja: Win Office 365
Pomógł: 3096 razy
Posty: 10263
Wysłany: 11-02-2021, 13:12   

stingtanner napisał/a:
gdzie takie hiperłącze miało by się tworzyć.
Z analizy pliku wynika, że chodzi o komórkę, w której wybrano coś z listy.

Zadanie zrozumiałem tak:
1. W kolumnach J:T mam listy sprawdzania poprawności.
2. Gdy z listy wybiorę NOK2, to w tej komórce ma się pojawić link do pustego maila.
3. W każdym innym przypadku (inny wybór z listy lub czyszczenie komórek) linka ma nie być.

Nie wiem czy Maciej Gonet by coś wyczarował z list walidacyjnych, by zrobić to bez makr. Ja taki biegły nie jestem, więc pozostaje mi tylko makro.
Procedurę należy wstawić do modułu arkusza Warstwa1 (nie do modułu standardowego, np Module1!):
Kod:
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngZakres   As Range
    Dim FontName    As String

    If Target.CountLarge > 1 Then Exit Sub

    'zakres wszystkich komórek zawierających walidację
    Set rngZakres = Me.Cells.SpecialCells(xlCellTypeAllValidation)

    If Not rngZakres Is Nothing Then
        'zakres komórek zawierających walidację w kolumnach J:T
        '(założono, że w tych kolumnach komórki zawierają listę)
        Set rngZakres = Intersect(rngZakres, Me.Columns("J:T"))
    Else
        Exit Sub
    End If

    'raczej nadmiarowe, ale strzeżonego Pan Bóg strzeże :-)
    If Not rngZakres Is Nothing Then

        'czy to zmiana w kolumnach J:T?
        If Not Intersect(Target, rngZakres) Is Nothing Then
            'czy w komórce jest teraz NOK2?
            If UCase(Target.Value) = "NOK2" Then
                'jest NOK2
                Application.EnableEvents = False
                With Target
                    'ponieważ wstawienie Hyperlinka powoduje zmianę formatu
                    'czcionki, to minimum działań, by przywrócić poprzedni stan
                    FontName = .Font.Name
                    .Formula = "=HYPERLINK(""mailto:"",""NOK2"")"
                    .Font.Name = FontName
                End With
                Application.EnableEvents = True
            Else
                'jest coś innego
                Target.Font.Underline = False
            End If 'UCase(Target...

            Target.Font.ColorIndex = xlAutomatic
           
        End If 'Not Intersect(Target...

    End If 'Not rngZakres Is Nothing

End Sub

Artik
_________________
Persistence is a virtue in the world of programming.
ID posta: 400170 Skopiuj do schowka
 
 
bart.rybka1 
Świeżak


Wersja: Win Office 2019
Posty: 2
Wysłany: 11-02-2021, 16:26   

Dokładnie chodzi o sprawę jak opisał to kolega Artik, ma to wyglądać tak że w przypadku wyboru z listy NOK2 ma tej komórce pojawić się hiperłącze odsyłające do pustego emaila. Dziękuje za pomoc.
ID posta: 400200 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe