Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 70438 Skopiuj do schowka Importowanie danych po wybraniu z listy rozwijanej
Autor Wiadomość
piatek149 
Świeżak


Wersja: Win Office 365
Posty: 5
  Wysłany: 16-03-2021, 17:05   Importowanie danych po wybraniu z listy rozwijanej

Witam wszystkich
potrzebuję aby samo mi pobierało nazwę sprzętu JM i sztuki z INRFA do SPIS po wybraniu pomieszczenia.
czy jest to możliwe bez makra???

link ondrive poniżej

>ciach<



Edit: Zefirek
Załączniki i zdjęcia załączamy na naszym forum Regulamin 1.2
ID posta: 402206 Skopiuj do schowka
 
 
piatek149 
Świeżak


Wersja: Win Office 365
Posty: 5
Wysłany: 17-03-2021, 11:06   załącznik

poniżej załącznik

sprzęt.xlsx
Pobierz Plik ściągnięto 13 raz(y) 308.58 KB

ID posta: 402240 Skopiuj do schowka
 
 
Tadek
Excel Expert


Wersja: Win Office 2007
Pomógł: 1985 razy
Posty: 5662
Wysłany: 24-03-2021, 08:33   

W załączeniu z makrem.

sprzęt (t).xlsm
Pobierz Plik ściągnięto 7 raz(y) 328.81 KB

ID posta: 402649 Skopiuj do schowka
 
 
Kaper 



Zaproszone osoby: 2
Wersja: Win Office 365
Pomógł: 4228 razy
Posty: 7959
Wysłany: 24-03-2021, 09:30   

Albo formułami. Żeby było ciut czytelniej wspólny fragment wyłączyłem jako kolumnę pomocniczą, ale oczywiście można ją włączyć w głąb formuł. Albo zostawić i np. nie włączać do obszaru drukowania, czy po prostu ukryć. Czyli w M8 ta pomocnicza formuła:
Kod:
=MIN.K(JEŻELI(PRZESUNIĘCIE(INFRA!$J$2:$J$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BH$1;0))="";"";WIERSZ(INFRA!$J$2:$J$163));WIERSZ(A1))

A potem w B8 (i kolejnych podobne, tylko z odwołaniem do innych kolumn spisu):
Kod:
=JEŻELI(CZY.LICZBA($M8);INDEKS(INFRA!C$1:C$163;$M8);"")

Dopiero ilość bardziej złożona, bo musimy odwołać się do kolumny z danymi z pomieszczenia, więc np. E8:
Kod:

=JEŻELI(CZY.LICZBA($M8);INDEKS(PRZESUNIĘCIE(INFRA!$J$1:$J$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BH$1;0));$M8);"")

(można też krócej z podwójnym indeksem)
Kod:
=JEŻELI(CZY.LICZBA($M8);INDEKS(INFRA!$K$1:$BH$163;$M8;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BH$1;0));"")

I to wszystko kopiujemy w dół


A na koniec jeszcze podmianka powtarzających się oznaczeń jednostek, czyli w D9 i kopia w dół:
Kod:
=JEŻELI(CZY.LICZBA($M9);JEŻELI(INDEKS(INFRA!E$1:E$163;$M9)=INDEKS(INFRA!E$1:E$163;$M8);"''";INDEKS(INFRA!E$1:E$163;$M9));"")


sprzęt.xlsx
Pobierz Plik ściągnięto 5 raz(y) 324.36 KB

_________________
Kaper Jej Królewskiej Mości :boss

Jeśli dane będą torturowane dość długo, przyznają się do wszystkiego
ID posta: 402656 Skopiuj do schowka
 
 
Bill Szysz 
Excel Expert


Wersja: Win Office 365
Pomógł: 898 razy
Posty: 3603
Wysłany: 24-03-2021, 09:59   

piatek149, skoro masz excelka365 to wykorzystajmy, do budowy formuł, funkcje w nim dostępne.
Komórka B8 arkusza SPIS
Kod:
=FILTRUJ(INFRA!$C$2:$C$163;INDEKS(INFRA!$K$2:$BJ$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BJ$1;0))<>"")

komórka D8
Kod:
=FILTRUJ(INFRA!$E$2:$E$163;INDEKS(INFRA!$K$2:$BJ$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BJ$1;0))<>"")

i kpmórka E8
Kod:
=FILTRUJ(INDEKS(INFRA!$K$2:$BJ$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BJ$1;0));I NDEKS(INFRA!$K$2:$BJ$163;0;PODAJ.POZYCJĘ($F$4;INFRA!$K$1:$BJ$1;0))<>"")

Gotowe
Pamiętaj, że te formuły wykorzystują mechanizm rozlewania więc w kolumnach B, D, E wyczyść wszystkie wpisane wartości poniżej komórki z wpisaną formułą (aż do końca Twojej tabelki czyli we wzorze do wiersza 35)

sprzęt_BS.xlsx
Pobierz Plik ściągnięto 7 raz(y) 351.5 KB

_________________
Zlecenia, konsultacje, doradztwo i szkolenia z Power Query, Power BI i Excela - Raporty, Analizy, Projekty
Pozdrawiam, były szbill62 aktualnie Bill Szysz
ID posta: 402658 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe