Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 63845 Skopiuj do schowka Skanowanie dokumentów w Paint.exe
Autor Wiadomość
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 18-01-2019, 09:54   Skanowanie dokumentów w Paint.exe

Dzień dobry.
Czy jest wykonalne aby z poziomu Excel-a:
-otworzyć nowy plik programu Paint
-wybrać/wykonać polecenie "ze skanera lub aparatu fotograficznego"
-zeskanować dokument
-zapisać w wybranej lokalizacji.
Dysponuję Excel2007.
ID posta: 360784 Skopiuj do schowka
 
 
Marecki 
Excel Expert



Wersja: Win Office 2019
Pomógł: 2079 razy
Posty: 6858
Wysłany: 18-01-2019, 23:15   

Generalnie to nie problem wykorzystując metodę SendKeys :
Kod:
Sub Paint()
    Dim prog        As String
    Dim id          As Double

    prog = "mspaint.exe"
    id = Shell(prog, vbMaximizedFocus)
    Application.Wait (Now + TimeValue("0:00:1"))

    Application.SendKeys ("%Pf")
    Application.Wait (Now + TimeValue("0:00:2"))
    Application.SendKeys ("s")


    Application.Wait (Now + TimeValue("0:00:20"))
    Application.SendKeys ("%Pz")
    '..... itd
End Sub

,ale myślę że nie tędy droga.
Metoda SendKeys potrafi być zawodna.

Może są w sieci aplikacje wykorzystujące API - dostęp bezpośredni do aplikacji, pozwalające na skanowanie ?
Ewentualnie pozostaje samo API pozwalające przejąć kontrolę nad danym okienkiem, ale to już nie dla mnie te progi.

Wiem że kolega Apollo dobrze się czuje w tych klimatach - API, ale czy podejmie temat to już tylko od niego zależy, o ile to będzie wykonalne.
_________________
Hardware - ta część komputera, którą można kopnąć kiedy software przestanie funkcjonować.

Szkolenia z Excela , FB
Office 2019 Professional Plus , Windows 10 x64
Pozdrawiam, były mkkk23 teraz Marecki.
ID posta: 360845 Skopiuj do schowka
 
 
apollo
ExcelSpec


Pomógł: 1229 razy
Posty: 4255
Wysłany: 19-01-2019, 00:27   

Marecki napisał/a:

Wiem że kolega Apollo dobrze się czuje w tych klimatach - API, ale czy podejmie temat to już tylko od niego zależy, o ile to będzie wykonalne.

Nie podejmę bo mam tylko XP Home, a Paint nie ma czegoś takiego jak "ze skanera lub aparatu fotograficznego", i nie mam podłączonego skanera. Nie ma, na czym testować.

Jeśli Paint w nowszym systemie to chyba nie ma klasycznego menu. Raczej Ribbon.

Ale pomysł mam ;-)

Propnuję: Otworzyć Paint ręcznie -> nacisnąć lewy Alt -> notować literę przy zakładce z tym "ze skanera lub aparatu fotograficznego", niech będzie P - od Plik (w angielskiej wersji chyba F - od File) -> -> nacisnąć P (F) -> menu Plik (File) się otwiera -> notować literę przy "ze skanera lub aparatu fotograficznego", niech np. X.

Potem kod uruchomi Paint -> Paint aktywny -> symulować naciśnięcie lewego Alt (keybd_event) -> symulować naciśnięcie P -> symulować naciśnięcie X.

Jeśli "ze skanera lub aparatu fotograficznego" ma skrót - kombinację klawiszy to od razu keybd_event z tym skrótem.

Ale cały czas to symulowanie. Wiem, jak dostać się do każdej pozycji menu przy klasycznym menu. Ribbon to już inna filozofia.
ID posta: 360849 Skopiuj do schowka
 
 
Artik 



Wersja: Win Office 365
Pomógł: 2609 razy
Posty: 8601
Wysłany: 19-01-2019, 01:48   

Johan napisał/a:
-zeskanować dokument
-zapisać w wybranej lokalizacji.
Czyli można olać Paint-a. :-)

Myślę, że trzeba iść w kierunku WIA lub starszego TWAIN-a.

Artik
_________________
Persistence is a virtue in the world of programming.
ID posta: 360853 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 19-01-2019, 11:04   

Na wstępie - jestem pełen podziwu patrząc na godziny dodania odpowiedzi!!!
Teraz w kolejności:
- kolega Marecki, kod działa tak jak to chciałem, bardzo dziękuję. Czy jest możliwość zastosowania polecenia w stylu;
- kolega apollo dziękuję za przystępne i "łopatologiczne" opisanie (w zasadzie tego co w swoim kodzie zawarł kol. Marecki). Teraz przynajmniej rozumiem co Marecki "zakodował" :hamer ;
- kolega Artik dziękuję za wskazówkę. Czy można olać? Ty może tak, ja jestem cienki bolek, ale obiecuję, że zna pewno poczytam, a gdyby coś z tego wyszło to pokażę.

Generalnie dziękuję za zainteresowanie i pomoc. To forum jest niezawodne. :beer
ID posta: 360863 Skopiuj do schowka
 
 
Marecki 
Excel Expert



Wersja: Win Office 2019
Pomógł: 2079 razy
Posty: 6858
Wysłany: 19-01-2019, 15:27   

No to WIA:
Kod:
Option Explicit
'https://docs.microsoft.com/pl-pl/previous-versions/windows/desktop/wiaaut/-wiaaut-consts-formatid


Sub Skanuj()
'Włączyć referencje do Microsoft Windows Image Acquisition
    Const dpi       As Long = 100 '  100 200 300 600 1200
    Dim FileName    As String
    Dim wiaImg      As New WIA.ImageFile
    Dim wiaDialog   As New WIA.CommonDialog
    Dim wiaScanner  As WIA.Device
    Dim i           As Long

    FileName = "skan.jpg"

    On Error Resume Next
    Set wiaScanner = wiaDialog.ShowSelectDevice(ScannerDeviceType, False, False)
    If Err <> 0 Then
        MsgBox "Brak dostępnych urządzeń WIA o wybranym typie, lub urządzenie jest wyłączone.", vbCritical
        Exit Sub
    End If
    On Error GoTo 0

    '    'Listuj właściwości skanera
    '    Range("A1:M1").Value = Array("Nr item", "IsReadOnly", "IsVector", "name", "PropertyID", "SubType", "SubTypeDefault", "SubTypeMax", "SubTypeMin", "SubTypeStep", "SubTypeValues", "Type", "Value")
    '    On Error Resume Next
    '    For i = 1 To 32
    '        Cells(i + 1, 1).Value = i
    '        Cells(i + 1, 2).Value = wiaScanner.Items(1).Properties.Item(i).IsReadOnly
    '        Cells(i + 1, 3).Value = wiaScanner.Items(1).Properties.Item(i).IsVector
    '        Cells(i + 1, 4).Value = wiaScanner.Items(1).Properties.Item(i).name
    '        Cells(i + 1, 5).Value = wiaScanner.Items(1).Properties.Item(i).PropertyID
    '        Cells(i + 1, 6).Value = wiaScanner.Items(1).Properties.Item(i).SubType
    '        Cells(i + 1, 7).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeDefault
    '        Cells(i + 1, 8).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMax
    '        Cells(i + 1, 9).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMin
    '        Cells(i + 1, 10).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeStep
    '        Cells(i + 1, 11).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeValues
    '        Cells(i + 1, 12).Value = wiaScanner.Items(1).Properties.Item(i).Type
    '        Cells(i + 1, 13).Value = wiaScanner.Items(1).Properties.Item(i).Value
    '    Next i
    '    On Error GoTo 0

    With wiaScanner.Items(1)

        .Properties("Current Intent").Value = 1                '0-nieokreślony 1-kolor 2-szary 4-czarny
        .Properties("Horizontal Resolution").Value = dpi       'DPI w poziomie
        .Properties("Vertical Resolution").Value = dpi         'DPI w pionie
        .Properties("Horizontal Start Position").Value = 0     'x punkt rozpoczynający skanowanie
        .Properties("Vertical Start Position").Value = 0       'y punkt rozpoczynający skanowanie
        .Properties("Horizontal Extent").Value = 8.27 * dpi    'Zakres poziomy dla A4
        .Properties("Vertical Extent").Value = 11.69 * dpi     'Zakres pionowy dla A4
        .Properties("Brightness").Value = 50                   'jasność


        'tak
        'Set wiaImg = .Transfer(wiaFormatJPEG)
        'lub tak:
        'Set wiaImg = wiaDialog.ShowAcquireImage(ScannerDeviceType, ColorIntent, MaximizeQuality, wiaFormatGIF, False)
        'lub tak:
        Set wiaImg = wiaDialog.ShowTransfer(wiaScanner.Items(1), wiaFormatJPEG, True)
    End With

    If Dir(ThisWorkbook.Path & "\" & FileName) <> "" Then
        Kill ThisWorkbook.Path & "\" & FileName
    End If

    wiaImg.SaveFile (ThisWorkbook.Path & "\" & FileName)

    Set wiaImg = Nothing
    Set wiaScanner = Nothing

End Sub

Dostosuj sobie rozdzielczość, ścieżkę zapisu, nazwę pliku itd...
Testuj

Edit:
Albo tak:
Kod:
Sub Test()
    Dim wiaDialog   As New WIA.CommonDialog
    Dim wiaImg      As New WIA.ImageFile

    Set wiaImg = wiaDialog.ShowAcquireImage(ScannerDeviceType, ColorIntent, MaximizeQuality, wiaFormatGIF, False)
    wiaImg.SaveFile (ThisWorkbook.Path & "\scan1.jpg")

End Sub
_________________
Hardware - ta część komputera, którą można kopnąć kiedy software przestanie funkcjonować.

Szkolenia z Excela , FB
Office 2019 Professional Plus , Windows 10 x64
Pozdrawiam, były mkkk23 teraz Marecki.
ID posta: 360876 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 20-01-2019, 15:46   

Ha, to jest dopiero bajka.
Znalazłem co nieco an temat WIA, nawet były samodzielne programy w VB, ale Twój kod wpasowany w Excel-a to jest mistrzostwo (dla mnie raczej nie osiągalne).
Twój kod bardzo pomoże w moim projekcie (będzie bardzo profesjonalnie).
Brak mi słów aby podziękować!!! :beer
ID posta: 360916 Skopiuj do schowka
 
 
Marecki 
Excel Expert



Wersja: Win Office 2019
Pomógł: 2079 razy
Posty: 6858
Wysłany: 25-01-2019, 20:11   

Johan, jeszcze mała poprawka kodu.
Pomimo tego że ustawiłem parametr wiaFormatJPEG by zapisywał plik w formacie JPEG, to i tak defacto otrzymywaliśmy plik BMP (nie patrz na rozszerzenie w nazwie pliku tylko na kompresję).
Przynajmniej u mnie tak to wychodzi.
Dlaczego tak się to zachowuje, nie wiem, może zależy to od urządzenia.
Zatem by uzyskać plik w danym formacie i zaoszczędzić miejsce dyskowe należy dokonać konwersji.
Nowy kod:
Kod:
Option Explicit
'https://docs.microsoft.com/pl-pl/previous-versions/windows/desktop/wiaaut/-wiaaut-consts-formatid

Sub Skanuj()
'Włączyć referencje do Microsoft Windows Image Acquisition
    Const dpi          As Long = 100    '  100 200 300 600 1200
    Dim IP             As New ImageProcess
    Dim wiaDialog      As New WIA.CommonDialog
    Dim Img            As New WIA.ImageFile
    Dim wiaScanner     As WIA.Device
    Dim FileName       As String

    FileName = "skan.jpg"

    On Error Resume Next
    Set wiaScanner = wiaDialog.ShowSelectDevice(ScannerDeviceType, False, False)
    If Err <> 0 Then
        MsgBox "Brak dostępnych urządzeń WIA o wybranym typie, lub urządzenie jest wyłączone.", vbCritical
        Exit Sub
    End If
    On Error GoTo 0

    '    'Listuj właściwości skanera
    '    Range("A1:M1").Value = Array("Nr item", "IsReadOnly", "IsVector", "name", "PropertyID", "SubType", "SubTypeDefault", "SubTypeMax", "SubTypeMin", "SubTypeStep", "SubTypeValues", "Type", "Value")
    '    On Error Resume Next
    '    For i = 1 To 32
    '        Cells(i + 1, 1).Value = i
    '        Cells(i + 1, 2).Value = wiaScanner.Items(1).Properties.Item(i).IsReadOnly
    '        Cells(i + 1, 3).Value = wiaScanner.Items(1).Properties.Item(i).IsVector
    '        Cells(i + 1, 4).Value = wiaScanner.Items(1).Properties.Item(i).name
    '        Cells(i + 1, 5).Value = wiaScanner.Items(1).Properties.Item(i).PropertyID
    '        Cells(i + 1, 6).Value = wiaScanner.Items(1).Properties.Item(i).SubType
    '        Cells(i + 1, 7).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeDefault
    '        Cells(i + 1, 8).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMax
    '        Cells(i + 1, 9).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMin
    '        Cells(i + 1, 10).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeStep
    '        Cells(i + 1, 11).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeValues
    '        Cells(i + 1, 12).Value = wiaScanner.Items(1).Properties.Item(i).Type
    '        Cells(i + 1, 13).Value = wiaScanner.Items(1).Properties.Item(i).Value
    '    Next i
    '    On Error GoTo 0

    With wiaScanner.Items(1)

        .Properties("Current Intent").Value = 1                '0-nieokreślony 1-kolor 2-szary 4-czarny
        .Properties("Horizontal Resolution").Value = dpi       'DPI w poziomie
        .Properties("Vertical Resolution").Value = dpi         'DPI w pionie
        .Properties("Horizontal Start Position").Value = 0     'x punkt rozpoczynający skanowanie
        .Properties("Vertical Start Position").Value = 0       'y punkt rozpoczynający skanowanie
        .Properties("Horizontal Extent").Value = 8.27 * dpi    'Zakres poziomy dla A4
        .Properties("Vertical Extent").Value = 11.69 * dpi     'Zakres pionowy dla A4
        .Properties("Brightness").Value = 50                   'jasność min -1000 max 1000
        .Properties("Contrast").Value = 150                    'Kontrast min -1000 max 1000

        'tak
        'Set Img = .Transfer(wiaFormatJPEG)
        'lub tak:
        'Set Img = wiaDialog.ShowAcquireImage(ScannerDeviceType, ColorIntent, MaximizeQuality, wiaFormatJPEG, False)
        'lub tak:
        Set Img = wiaDialog.ShowTransfer(wiaScanner.Items(1), wiaFormatJPEG, True)
    End With

    If Dir(ThisWorkbook.Path & "\" & FileName) <> "" Then Kill ThisWorkbook.Path & "\" & FileName

    Set IP = CreateObject("Wia.ImageProcess")
    IP.Filters.Add IP.FilterInfos("Convert").FilterID
    IP.Filters(1).Properties("FormatID").Value = wiaFormatJPEG
    Set Img = IP.Apply(Img)
    Img.SaveFile (ThisWorkbook.Path & "\" & FileName)

    Set Img = Nothing
    Set wiaScanner = Nothing
    Set wiaDialog = Nothing
    Set IP = Nothing

End Sub
_________________
Hardware - ta część komputera, którą można kopnąć kiedy software przestanie funkcjonować.

Szkolenia z Excela , FB
Office 2019 Professional Plus , Windows 10 x64
Pozdrawiam, były mkkk23 teraz Marecki.
ID posta: 361321 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 27-01-2019, 12:42   

Bardzo dziękuję za nauki ciąg dalszy. :hamer
Rzeczywiście różnica jest znacząca (zwłaszcza, że skanów będzie "troszkę").
W pierwszej wersji 2,76 MB, a w drugiej już tylko 362 kB.

PS.
Z jakiegoś powodu wyrzucił mi błąd w tej linii:
Kod:
.Properties("Contrast").Value = 150                    'Kontrast min -1000 max 1000
W poprzedniej wersji tej właściwości nie było.
Linię "odhaczyłem" i zadziałało.
Jeszcze raz bardzo dziękuję. :beer
ID posta: 361393 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 13-03-2019, 17:38   

Dzień dobry.
Mam świadomość, że mogę zostać posądzony o malkontenctwo :oops: , ale mam jeszcze jedno pytanie.
Czy w/w kodzie można dokonać modyfikacji, aby zapisać skanowany obraz w formacie (do pliku) pfd?
ID posta: 364147 Skopiuj do schowka
 
 
Marecki 
Excel Expert



Wersja: Win Office 2019
Pomógł: 2079 razy
Posty: 6858
Wysłany: 13-03-2019, 22:13   

Zależne od wersji Excela , ale sprawdź:
Kod:
Sub Skanuj()
'Włączyć referencje do Microsoft Windows Image Acquisition
    Const dpi          As Long = 100    '  100 200 300 600 1200
    Dim IP             As New ImageProcess
    Dim wiaDialog      As New WIA.CommonDialog
    Dim Img            As New WIA.ImageFile
    Dim wiaScanner     As WIA.Device
    Dim FileName       As String
    Dim FileNamePDF    As String
    Dim sh             As Object

    FileName = "skan.jpg"
    FileNamePDF = "skan.pdf"

    On Error Resume Next
    Set wiaScanner = wiaDialog.ShowSelectDevice(ScannerDeviceType, False, False)
    If Err <> 0 Then
        MsgBox "Brak dostępnych urządzeń WIA o wybranym typie, lub urządzenie jest wyłączone.", vbCritical
        Exit Sub
    End If
    On Error GoTo 0

    '        'Listuj właściwości skanera
    '        Range("A1:M1").Value = Array("Nr item", "IsReadOnly", "IsVector", "name", "PropertyID", "SubType", "SubTypeDefault", "SubTypeMax", "SubTypeMin", "SubTypeStep", "SubTypeValues", "Type", "Value")
    '        On Error Resume Next
    '        For i = 1 To 32
    '            Cells(i + 1, 1).Value = i
    '            Cells(i + 1, 2).Value = wiaScanner.Items(1).Properties.Item(i).IsReadOnly
    '            Cells(i + 1, 3).Value = wiaScanner.Items(1).Properties.Item(i).IsVector
    '            Cells(i + 1, 4).Value = wiaScanner.Items(1).Properties.Item(i).Name
    '            Cells(i + 1, 5).Value = wiaScanner.Items(1).Properties.Item(i).PropertyID
    '            Cells(i + 1, 6).Value = wiaScanner.Items(1).Properties.Item(i).SubType
    '            Cells(i + 1, 7).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeDefault
    '            Cells(i + 1, 8).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMax
    '            Cells(i + 1, 9).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeMin
    '            Cells(i + 1, 10).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeStep
    '            Cells(i + 1, 11).Value = wiaScanner.Items(1).Properties.Item(i).SubTypeValues
    '            Cells(i + 1, 12).Value = wiaScanner.Items(1).Properties.Item(i).Type
    '            Cells(i + 1, 13).Value = wiaScanner.Items(1).Properties.Item(i).Value
    '        Next i
    '        On Error GoTo 0

    With wiaScanner.Items(1)

        .Properties("Current Intent").Value = 1                '0-nieokreślony 1-kolor 2-szary 4-czarny
        .Properties("Horizontal Resolution").Value = dpi       'DPI w poziomie
        .Properties("Vertical Resolution").Value = dpi         'DPI w pionie
        .Properties("Horizontal Start Position").Value = 0     'x punkt rozpoczynający skanowanie
        .Properties("Vertical Start Position").Value = 0       'y punkt rozpoczynający skanowanie
        .Properties("Horizontal Extent").Value = 8.27 * dpi    'Zakres poziomy dla A4
        .Properties("Vertical Extent").Value = 11.69 * dpi     'Zakres pionowy dla A4
        .Properties("Brightness").Value = 50                   'jasność min -1000 max 1000
        .Properties("Contrast").Value = 150                    'Kontrast min -1000 max 1000

        'tak
        'Set Img = .Transfer(wiaFormatJPEG)
        'lub tak:
        'Set Img = wiaDialog.ShowAcquireImage(ScannerDeviceType, ColorIntent, MaximizeQuality, wiaFormatJPEG, False)
        'lub tak:
        Set Img = wiaDialog.ShowTransfer(wiaScanner.Items(1), wiaFormatJPEG, True)
    End With

    If Dir(ThisWorkbook.path & "\" & FileName) <> "" Then Kill ThisWorkbook.path & "\" & FileName

    Set IP = CreateObject("Wia.ImageProcess")
    IP.Filters.Add IP.FilterInfos("Convert").FilterID
    IP.Filters(1).Properties("FormatID").Value = wiaFormatJPEG
    Set Img = IP.Apply(Img)
    Img.SaveFile (ThisWorkbook.path & "\" & FileName)

    Set sh = Sheets.Add
    sh.Pictures.Insert (ThisWorkbook.path & "\" & FileName)
    sh.ExportAsFixedFormat Type:=xlTypePDF, FileName:=ThisWorkbook.path & "\" & FileNamePDF

    Application.DisplayAlerts = False
    sh.Delete
    Application.DisplayAlerts = True

    Set Img = Nothing
    Set wiaScanner = Nothing
    Set wiaDialog = Nothing
    Set IP = Nothing
    Set sh = Nothing
End Sub
_________________
Hardware - ta część komputera, którą można kopnąć kiedy software przestanie funkcjonować.

Szkolenia z Excela , FB
Office 2019 Professional Plus , Windows 10 x64
Pozdrawiam, były mkkk23 teraz Marecki.
ID posta: 364172 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 14-03-2019, 18:01   

W Ex2007 zadziałało. Dziękuję bardzo.
Ale podrążę jeszcze troszkę. Czy można ominąć wstawienie .jpg do arkusza? Chodzi mi o coś w stylu
Kod:
Img.SaveFile (ThisWorkbook.path & "\skan.pdf")
ID posta: 364239 Skopiuj do schowka
 
 
Marecki 
Excel Expert



Wersja: Win Office 2019
Pomógł: 2079 razy
Posty: 6858
Wysłany: 14-03-2019, 19:38   

Johan napisał/a:
Czy można ominąć wstawienie .jpg do arkusza?
Jak masz pełnego Adobe Acrobat Reader to można.
_________________
Hardware - ta część komputera, którą można kopnąć kiedy software przestanie funkcjonować.

Szkolenia z Excela , FB
Office 2019 Professional Plus , Windows 10 x64
Pozdrawiam, były mkkk23 teraz Marecki.
ID posta: 364242 Skopiuj do schowka
 
 
Johan 
Stały bywalec Excelforum


Pomógł: 87 razy
Posty: 299
Wysłany: 15-03-2019, 14:15   

Rozumiem. Sprawa dotyczy nie tylko mojego komputera więc to nie będzie dobry kierunek. Będę musiał korzystać ze wstawiania .jpg do arkusza.
Dziękuję bardzo za dotychczasową pomoc. :beer
Pozdrawiam.
ID posta: 364304 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe