Excel Forum - Porady, Pomoc,  Excel Help, Excel FAQ Strona Główna
 FAQ  RegulaminRegulamin  Szukaj   Użytkownicy   Grupy   Rejestracja   Profil   Twoje wiadomości   Zaloguj 


Poprzedni temat «» Następny temat
ID tematu: 64048 Skopiuj do schowka Jak obliczyć ilość zamówień
Autor Wiadomość
PUNDIT
świeżak


Posty: 2
Wysłany: 05-02-2019, 20:09   Jak obliczyć ilość zamówień

Witam,
Mam takie oto zadanie - jak obliczyć ilość zamówień dla danego kodu (kolumna E), biorąc pod uwagę że w jednym sklepie mógł być sprzedawany ten sam produkt wiele razy w różnym czasie, a dodatkowo sklep może mieć tą samą nazwę i różne adresy. Mogło być też sprzedanych kilka produktów podczas jednej wizyty. Skróciłem listę do jednego Kodu kolumna E.

Plik przykładowy.xlsx
Pobierz Plik ściągnięto 18 raz(y) 21.88 KB

ID posta: 362019 Skopiuj do schowka
 
 
kuma 
Excel Expert


Wersja: Win Office 2010
Pomógł: 1217 razy
Posty: 3613
Wysłany: 05-02-2019, 21:04   

Witaj na forum. Bardzo słabo opisałeś swój problem. Nie wiem, czy dobrze zrozumiałem intencje.
Wynik jest w 'K2'
Kod:
Sub LiczZamowienia()
    Dim a()
    Dim i As Long
    Dim d As Object
    Dim ms As String
   
    Set d = CreateObject("scripting.dictionary")
    With Sheets("Arkusz1")
        a = .Range("A2:I" & .Cells(Rows.Count, "A").End(xlUp).Row).Value
        For i = 1 To UBound(a)
            ms = a(i, 4) & a(i, 5) & a(i, 6) & a(i, 7) & a(i, 8)
            d(ms) = Empty
        Next
        .[K2] = d.Count
    End With
    Set d = Nothing
End Sub
Pozdrawiam.
ID posta: 362022 Skopiuj do schowka
 
 
PUNDIT
świeżak


Posty: 2
Wysłany: 05-02-2019, 22:05   

Dzięki, rozumiem, że to tylko przez VBA. A co gdyby w kolumnie Kod były np. 50 różnych kodów (każdy kod to inny handlowiec), a my chcemy policzyć ilość zamówień dla każdego z nich.
ID posta: 362029 Skopiuj do schowka
 
 
bodek 


Wersja: Win Office 2016
Pomógł: 948 razy
Posty: 2713
Wysłany: 05-02-2019, 22:18   

PUNDIT napisał/a:
rozumiem, że to tylko przez VBA.
nie, nie, poprzez Power Query szybciej, elastyczniej itd
Przykład, jak mniemam również niezrozumiały (bo to nowość) w załączniku.

Plik przykładowyPQ.xlsx
Pobierz Plik ściągnięto 13 raz(y) 37.46 KB

_________________
Szkolenia z Excela, Power Query, Power Pivot, wizualizacje danych w Excelu
ID posta: 362032 Skopiuj do schowka
 
 
kuma 
Excel Expert


Wersja: Win Office 2010
Pomógł: 1217 razy
Posty: 3613
Wysłany: 05-02-2019, 23:37   

Za pomocą VBA, przy wielu kodach mogłoby wyglądać jak niżej.
Tabela wyników zaczyna się od 'K3'
Kod:
Sub LiczZamowienia()
    Dim a(), k
    Dim i As Long
    Dim d As Object, lst As Object
    Dim ms As String
   
    Set d = CreateObject("scripting.dictionary")
    Set lst = CreateObject("System.Collections.ArrayList")
    With Sheets("Arkusz1")
        a = .Range("A2:I" & .Cells(Rows.Count, "A").End(xlUp).Row).Value
        With d
            For i = 1 To UBound(a)
                ms = a(i, 4) & a(i, 6) & a(i, 7) & a(i, 8)
                If .exists(a(i, 5)) Then
                    If .Item(a(i, 5)).exists(ms) Then
                        .Item(a(i, 5)).Item(ms) = .Item(a(i, 5)).Item(ms) + 1
                    Else
                         .Item(a(i, 5)).Item(ms) = 1
                    End If
                Else
                    Set .Item(a(i, 5)) = CreateObject("Scripting.Dictionary")
                    .Item(a(i, 5)).Item(ms) = 1
                    lst.Add a(i, 5)
                End If
            Next
        End With
        lst.Sort
        i = 3
        .[K3].CurrentRegion.ClearContents
        .Cells(3, "K").Resize(, 2) = Array("KOD", "Ilość zam.")
        For Each k In lst
            i = i + 1
            .Cells(i, "K") = k
            .Cells(i, "L") = d.Item(k).Count
        Next k
    End With
    Set d = Nothing
    Set lst = Nothing
End Sub
Pozdrawiam.
ID posta: 362040 Skopiuj do schowka
 
 
Wyświetl posty z ostatnich:   
Odpowiedz do tematu
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
Nie możesz załączać plików na tym forum
Możesz ściągać załączniki na tym forum
Dodaj temat do Ulubionych
Wersja do druku

Skocz do:  

Powered by phpBB modified by Przemo © 2003 phpBB Group
Theme xandgreen created by spleen& Programosy modified v0.3 by warna
Opieka techniczna www.marketingNET.pl

Archiwum

Strona używa plików cookies.

Kliknij tutaj, żeby dowiedzieć się jaki jest cel używania cookies oraz jak zmienić ustawienia cookie w przeglądarce.
Korzystając ze strony użytkownik wyraża zgodę na używanie plików cookies, zgodnie z bieżącymi ustawieniami przeglądarki.
Sprawdź, w jaki sposób przetwarzamy dane osobowe